mirror of
https://github.com/GoldenCheetah/GoldenCheetah.git
synced 2026-02-13 16:18:42 +00:00
2681536c68
Using qwt from https://sourceforge.net/p/qwt/git/ci/qwt-multiaxes/tree/ Applied the following changes to qwt 6.3: * Added QwtZone to qwt_plot_curve.cpp * Disabled the emitting of Layout Requests on geometry changes of QwtScaleWidget - without this, CPU utilization was up to 100% on one core Fixes #4495
76 lines
1.4 KiB
Plaintext
76 lines
1.4 KiB
Plaintext
######################################################################
|
|
# Qwt Examples - Copyright (C) 2002 Uwe Rathmann
|
|
# This file may be used under the terms of the 3-clause BSD License
|
|
######################################################################
|
|
|
|
QWT_ROOT = $${PWD}/..
|
|
include( $${QWT_ROOT}/qwtconfig.pri )
|
|
include( $${QWT_ROOT}/qwtbuild.pri )
|
|
include( $${QWT_ROOT}/qwtfunctions.pri )
|
|
|
|
QWT_OUT_ROOT = $${OUT_PWD}/../..
|
|
|
|
TEMPLATE = app
|
|
|
|
INCLUDEPATH += $${QWT_ROOT}/src
|
|
DEPENDPATH += $${QWT_ROOT}/src
|
|
|
|
INCLUDEPATH += $${QWT_ROOT}/classincludes
|
|
DEPENDPATH += $${QWT_ROOT}/classincludes
|
|
|
|
!debug_and_release {
|
|
|
|
DESTDIR = $${QWT_OUT_ROOT}/examples/bin
|
|
}
|
|
else {
|
|
CONFIG(debug, debug|release) {
|
|
|
|
DESTDIR = $${QWT_OUT_ROOT}/examples/bin_debug
|
|
}
|
|
else {
|
|
|
|
DESTDIR = $${QWT_OUT_ROOT}/examples/bin
|
|
}
|
|
}
|
|
|
|
QMAKE_RPATHDIR *= $${QWT_OUT_ROOT}/lib
|
|
qwtAddLibrary($${QWT_OUT_ROOT}/lib, qwt)
|
|
|
|
greaterThan(QT_MAJOR_VERSION, 4) {
|
|
|
|
QT += printsupport
|
|
QT += concurrent
|
|
}
|
|
|
|
greaterThan(QT_MAJOR_VERSION, 5) {
|
|
|
|
win32:CONFIG += entrypoint
|
|
}
|
|
|
|
contains(QWT_CONFIG, QwtOpenGL ) {
|
|
|
|
QT += opengl
|
|
|
|
greaterThan(QT_MAJOR_VERSION, 5) {
|
|
QT += openglwidgets
|
|
}
|
|
}
|
|
else {
|
|
|
|
DEFINES += QWT_NO_OPENGL
|
|
}
|
|
|
|
contains(QWT_CONFIG, QwtSvg) {
|
|
|
|
QT += svg
|
|
}
|
|
else {
|
|
|
|
DEFINES += QWT_NO_SVG
|
|
}
|
|
|
|
|
|
contains(QWT_CONFIG, QwtDll) {
|
|
DEFINES += QT_DLL QWT_DLL
|
|
}
|